3 replies to this topic

[FourWhey]

After a row is added, I set the hint.  At runtime, if I mouse over the cell, nothing is shown. The column's ShowTextFitHint is false.

 

Here's how I assign the hint text.

grd.Cell[grd.Columns.ItemBy['InventoryNumber'].Index, grd.LastAddedRow].Hint := 'test';

Is this just not implemented or is something wrong?

 

Almost identical code worked in v5.

 

Thanks.

[Boki (Berg)]

Hi,

Most probably bug. I will fix it, it's should be easy.

[Boki (Berg)]

Hi,

Replace next procedure inside NxGridView6.pas file (Sources\Next Grid):

Please tell me if it work.

procedure TNxGridView6.SetHoverCell(const Value: TPoint);
var
  Cell: INxBaseCell;
  GridCell: INxCell;
  CellRect: TRect;
  Location: TPoint;
  TextContent: INxTextContent;
  View: INxColumnView;
begin
  if not IsEqual(FHotCell, Value) then
  begin

    ReleaseCellHint;
    ReleaseTextFitHint;

    if Assigned(FCapturedView) then
    begin
      { Can't capture! }
      if FCapturedView.Captured
        then Exit;

      { Unset Hover }
      FCapturedView.MouseLeave;

      { Release }
      FCapturedView := nil;
    end;

    { Set Value }

    FHotCell := Value;

    if IsSet(FHotCell)
      and Columns[FHotCell.X].Enabled then
    begin

      { IsResponsive Checked inside
        Set & Clone }
      CaptureView(FHotCell);

      if FHotCell.Y = -1 then
      begin
        Cell := Columns[FHotCell.X].InsertValue;
        CellRect := GetCellRect(FHotCell.X);
      end else
      begin
        Cell := Cells[FHotCell.X, FHotCell.Y];
        CellRect := GetCellRect(FHotCell);
      end;

      if Supports(Columns[FHotCell.X], INxTextContent, TextContent) then
        if TextContent.ShowTextFitHint then
        begin
          if not Cell.Visible then Exit;

          View := UpdateCellView(FHotCell.X, FHotCell.Y, CellRect);

          if not View.CanFitText then
          begin
            Location := CellRect.TopLeft;

            ShowCellTextFitHint(Location, Columns[FHotCell.X].GetDisplayText(Cell, FHotCell.X, FHotCell.Y));
          end;

        end;

      { Cell's Hint }
      if Supports(Cell, INxCell, GridCell) then
        if GridCell.Hint <> '' then
        begin
          Location := GetCellRect(FHotCell).TopLeft;
          OffsetPoint(Location, Columns[FHotCell.X].Width, 0);

          ShowCellHint(Location, GridCell.Hint);
        end;

    end
    else Unset(FHotCell);

  end;

end;

[FourWhey]

This worked.  Thank you.